; 
.set		TCCR0_INIT = CLK1024
.set		TCNT0_INIT = 128
.set		TIMSK_INIT = (1<<TOIE0)
.set		PORTD_INIT = 0
.set		DDRD_INIT  = 0b011011
.set		MOTOR	   = PORTD

.def		Step_state = r16	; Current output pin state
.def		Step_dir   = r17	; Count (+/-) steps to turn

;
; EEPROM Segment
;
		.eseg
		.org	0
Step_tbl:	.db	0b000001
		.db	0b001001	; Half step
		.db	0b001000
		.db	0b001010	; Half step
		.db	0b000010
		.db	0b010010	; Half step
		.db	0b010000
		.db	0b010001	; Half step
Tbl_end:

.equ		ST_Len = (Tbl_end - Step_tbl)

Clock:		.db	TCCR0_INIT		; pre-scale
Timer_cnt:	.db	TCNT0_INIT		; overflow count

;
; Code
; 
		.cseg

timer_interrupt:
		ldi	temp, Timer_cnt
		out	EEAR, temp
		sbi	EECR, EERE
		in	temp, EEDR
		out	TCNT0, temp

		rcall	sw_read
		rcall	step

		reti
;
; Handles state transistions for a single stepper.
;
step:
		tst	Step_dir
		brlt	step_rev
		breq	step_stop
step_fwd:
		dec	Step_dir
		inc	Step_state
		cpi	Step_state, ST_Len	; if > last then set to zero
		brne	step_x
		clr	Step_state
		rjmp	step_x
step_rev:	
		inc	Step_dir
		dec	Step_state
		brge	step_x			; 
		ldi	Step_state, (ST_Len-1)	; if < zero, then set to last

step_x:		out	EEAR, Step_State	; Table starts at Zero
		sbi	EECR, EERE
		in	temp, EEDR
		out	MOTOR, temp

step_stop:	ret

;
; Initialize the various stepper paramters
;
step_init:	
		clr	Step_state
		clr	Step_dir
		ret