;***** Pin definitions

.equ	RxD	= PD2
.equ	TxD	= PD4
.equ	RxPORT	= PIND
.equ	TxPORT	= PORTD

.equ	RxRdy	= 7

.set	DDRD_INIT = DDRD_INIT + (1<<TxD)	; Rx is input (default)
.set	PORTD_INIT= PORTD_INIT + (1<<TxD)	; Set Tx 1, Stop bit.

;.set	GIMSK_INIT = (1<<INT0)			; enable external interrupts
;.set	MCUCR_INIT = MCUCR_INIT | (1<< isc01)	; default to low level interrupt

;***** Global register variables - define in MAIN.ASM
;
;.def	bitcnt	=R16			;bit counter
;.def	temp	=R17			;temporary storage register;;
;
;.def	Txbyte	=R18			;Data to be transmitted
;.def	RXbyte	=R19			;Received data
;.def	U_Flags = high

	.cseg

;***************************************************************************
;*
;* "putchar"
;*
;* This subroutine transmits the byte stored in the "Txbyte" register
;* The number of stop bits used is set with the sb constant
;*
;* Number of words	:14 including return
;* Number of cycles	:Depens on bit rate
;* Low registers used	:None
;* High registers used	:2 (bitcnt,Txbyte)
;* Pointers used	:None
;*
;***************************************************************************
.equ		sb	=1		;Number of stop bits (1, 2, ...)

putchar:	ldi	bitcnt,9+sb	;1+8+sb (sb is # of stop bits)
		com	Txbyte		;Inverte everything
		sec			;Start bit

putchar0:	brcc	putchar1	;If carry set
		cbi	TxPORT,TxD	;    send a '0'
		rjmp	putchar2	;else	

putchar1:	sbi	TxPORT,TxD	;    send a '1'
		nop

putchar2:	rcall UART_delay	;One bit delay
		rcall UART_delay

		lsr	Txbyte		;Get next bit - Last bits will be 0 (stop)
		dec	bitcnt		;If not all bit sent
		brne	putchar0	;   send next
					;else
		ret			;   return


;***************************************************************************
;*
;* "getchar"
;*
;* This subroutine receives one byte and returns it in the "Rxbyte" register
;*
;* Number of words	:14 including return
;* Number of cycles	:Depens on when data arrives
;* Low registers used	:None
;* High registers used	:2 (bitcnt,Rxbyte)
;* Pointers used	:None
;*
;***************************************************************************

getchar:	sbic 	RxPORT,RxD	;Wait for start bit
		rjmp 	getchar
		rjmp	extern_interrupt


;*************************************************************************
;
; Extern_Interrupt
;
; We use the external interrup to trigger the usart input routine.
; communications to the main routine is via a flag (RxRdy)
;
; The idea here is that the robot can have communications facilities
; that cost no cycles unless used.  When used, things will foul up, but,
; so what.
;
; Need to get the sense of the interrupt correct so it is triggered only
; on the start bit.
;

Extern_interrupt:
	ldi 	bitcnt,9	;8 data bit + 1 stop bit

	rcall UART_delay	;0.5 bit delay		; Start bit

E1:	rcall UART_delay	;1 bit delay		; first bit.
	rcall UART_delay		

	clc			;clear carry
	sbic 	RxPORT,RxD	;if RX pin high
	sec			;   Set carry

	dec 	bitcnt		;If bit is stop bit
	breq 	e2		;   return
				;else
	ror 	Rxbyte		;   shift carry bit into Rxbyte
	rjmp 	E1		;   go get next

E2:	sbr	U_Flag, RxRdy
	reti

;***************************************************************************
;*
;* "UART_delay"
;*
;* This delay subroutine generates the required delay between the bits when
;* transmitting and receiving bytes. The total execution time is set by the
;* constant "b":
;*
;*	b = (Clock/(2*baud)-7)/3 
;*
;* 3·b + 7 cycles (including rcall and ret)
;*
;* Number of words	:4 including return
;* High registers used	:1 (temp)
;*
.equ	Clock	= 4000000
.equ	baud	= 19200


UART_delay:	ldi	temp, ((Clock/(baud * 2)) - 7)/3
UART_delay1:	dec	temp
		brne	UART_delay1

		ret